
**Quarter-to-date over full previous quarter**

As the name indicates, the quarter-to-date over the full previous quarter compares the quarter-to-date against the entire previous quarter. Figure 10 shows that in May 2009, Sales QTD exceeded the value of Sales Amount for the entire previous quarter (Q1-2009). Sales QTDOPQ% provides an immediate comparison of the quarter-to-date with the total of the previous quarter; it shows growth over the previous quarter when the percentage is positive, which is the case in May and June 2009.



The quarter-to-date-over-previous-quarter growth is computed by using the Sales QTDOPQ and Sales QTDOPQ % measures; these in turn rely on the Sales QTD measure to compute the quarter-to-date value and on the Sales PQC measure to get the sales amount of the entire previous quarter:

Sales PQC :=

VAR CurrentYearQuarterNumber = SELECTEDVALUE ( 'Date'[Year Quarter Number] )

VAR PreviousYearQuarterNumber = CurrentYearQuarterNumber - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Quarter Number] = PreviousYearQuarterNumber

    )

RETURN

    Result

Sales QTDOPQ :=

VAR ValueCurrentPeriod = [Sales QTD]

VAR ValuePreviousPeriod = [Sales PQC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QTDOPQ % :=

DIVIDE (


    [Sales QTDOPQ],

    [Sales PQC]

)

or

The quarter-to-date over full previous quarter compares the quarter-to-date against the entire previous quarter. Sales QTDOPQ% provides an immediate comparison of the quarter-to-date with the total of the previous quarter; it shows growth over the previous quarter when the percentage is positive, as is the case starting in May 2008.



The quarter-to-date-over-previous-quarter growth is computed with the Sales QTDOPQ and Sales QTDOPQ % measures; these rely on the Sales QTD measure to compute the quarter-to-date value and on the Sales PQC measure to get the sales amount of the entire previous quarter:

Sales PQC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Quarter] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, QUARTER )

    )

)

Sales QTDOPQ :=

VAR ValueCurrentPeriod = [Sales QTD]

VAR ValuePreviousPeriod = [Sales PQC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QTDOPQ % :=

DIVIDE (

    [Sales QTDOPQ],

    [Sales PQC]

)

The Sales PQC measure can also be written using [**PREVIOUSQUARTER**](https://dax.guide/previousquarter/?aff=dax-patterns), as long as it is not used at the year level for more than one quarter:

Sales PQC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Quarter] ),

    CALCULATE (

        [Sales Amount],

        PREVIOUSQUARTER ( 'Date'[Date] )

    )

)